buildscript {
	repositories {
		mavenLocal()
		mavenCentral()
		maven { url "https://repo.maven.apache.org/maven2" }
		maven { url "https://plugins.gradle.org/m2/" }
		jcenter()
	}
	dependencies {
		classpath 'org.jooq:jooq-codegen:3.18.6'
		classpath 'org.postgresql:postgresql:42.6.0'
		classpath 'org.jfrog.buildinfo:build-info-extractor-gradle:latest.release'
		classpath 'nu.studer.jooq:nu.studer.jooq.gradle.plugin:8.2.1'
	}
}

plugins {
  id 'nu.studer.jooq' version '8.2.1'
}

apply plugin: 'java'
apply plugin: 'maven-publish'
apply plugin: 'eclipse'

group = 'de.jottyfan'
version = '20240109'
def artifactId = 'timetrackjooq'
def versionNumber = version

description = """timetrackjooq"""

sourceCompatibility = 17
targetCompatibility = 17

tasks.withType(JavaCompile) {
	options.encoding = 'UTF-8'
}

repositories {
	mavenLocal()
	mavenCentral()
	maven { url "https://repo.maven.apache.org/maven2" }
}

dependencies {
	implementation 'org.jooq:jooq:3.18.6'
	implementation 'org.jooq:jooq-codegen:3.18.6'
	
	implementation 'org.postgresql:postgresql:42.6.0'
	
	jooqGenerator 'org.postgresql:postgresql:42.6.0'
}

jooq {
	edition = nu.studer.gradle.jooq.JooqEdition.OSS
	version = '3.18.6'
	configurations {
	  timetrack {
	    generateSchemaSourceOnCompilation = false
	    generationTool {
	      logging = org.jooq.meta.jaxb.Logging.WARN 
		    jdbc {
			    driver = 'org.postgresql.Driver'
			    url = 'jdbc:postgresql://localhost:5432/timetrack'
					user = 'jooq'
					password = 'jooq'						
		    }
		    generator {
		    	name = 'org.jooq.codegen.DefaultGenerator'
		    	database {
		    		name = 'org.jooq.meta.postgres.PostgresDatabase'
		    		schemata {
		    			schema {
		    				inputSchema = 'done'
		    			}
		    			schema {
		    				inputSchema = 'profile'
		    			}
		    			schema {
		    				inputSchema = 'contact'
		    			}
		    			schema {
		    				inputSchema = 'note'
		    			}
		    		}
		    		includes = '.*'
		    	}
		    	generate {
		    	    relations = true
		    	    records = true
		    	}
		    	target {
		    		packageName = 'de.jottyfan.timetrack.db'
		    		directory = 'src/main/java'
		    	}
		    }
		  }
		}
	}
}

publishing {
	publications {
		binary(MavenPublication) {
			from components.java
		}
	}
  repositories {
    maven {
    	url = layout.buildDirectory.dir("/home/henkej/git/libs/")
    }
  }
}

// removes the task dependency from compileJava to generateTimetrackJooq
project.tasks.getByName('compileJava').dependsOn -= 'generateTimetrackJooq'